"Connect" by James Hudson

The story genre is "Science Fiction/Fantasy". The release number is 1. The story headline is "A short story". The story description is "You huddle in the concrete cell. Ever since the Hedonans built their outpost in the valley near your village, you never gave them any reason to single you out. Maybe it has something to do with the strange box that you found in a mountain cave the other week?"

When play begins: say "
[italic type]You huddle in the concrete cell. Ever since the Hedonans built their outpost in the valley near your village, you never gave them any reason to single you out. Maybe it has something to do with the strange black box that you found recently? You glance furtively through the bars of the cell, then take the box from under your cloak. It to whirs into life and a small panel slides out, curiously marked like a typewriter...[roman type]

---

[bold type]        --- Welcome to DefenceNet Terminal v0.9 ---[roman type][paragraph break]
WARNING: This hardware is for approved military use only.[paragraph break]
> Local units found...[line break]
>   - organic neural interface (signal strength: [a random number from 50 to 100]%).[line break]
>   - multiple neural interface fragments (combined signal strength: low).[line break]
> Checking Memory integrity... done! (viable Memory in subject's DNA: [a random number from 2 to 30]%).[paragraph break]
        --- Brainpin Neural Interface --- [line break]
WARNING: Graphics hardware not found, text interface only. The unit's perceptions will be rendered in human-readable prose.[line break]
You have access to the unit's brain via text commands such as:[line break]
 -   TAKE, GO, PUSH, PUT, REMEMBER, ASK, or TELL[line break]
Network extensions for current unit:[line break]
 -   HELP - online assistance for new operators.[line break]
 -   CONNECT - toggles network amplifier. Can also be toggled by touching the base of the skull. Do not operate heavy machinery while Connected![line break]
   OK>[line break]
" 

Part 1 - Modifications to the World Model

Chapter 1 - Connecting
[Connecting is a special ability shared by those who have a brain-pin. One of its uses is to communicate with others or read their emotions, or to access fragments of Memory. Connection only lasts a limited amount of time, before the player needs to recharge. Also, moving around or performing actions is impossible.]

Understand "c" or "connect" or "activate" or "touch neck" or "touch skull" or "touch head" or "touch my head" as connecting. Connecting is an action applying to nothing.

Understand "unconnect" or "disconnect" or "deactivate" as unconnecting. Unconnecting is an action applying to nothing.

Brainpin state is a kind of value. The brainpin states are connected and unconnected. The player has brainpin state. The player is unconnected. 

Carry out unconnecting:
  If the player is connected, try connecting;
  otherwise say "You are already unconnected - the world appears reassuringly normal.";

Carry out connecting:
  If the player is connected, now the player is unconnected;
  otherwise now the player is connected;

Report connecting:
  If the player is connected, say "You raise your hand to your neck, and [one of]finger the scar at the base of your skull. The brainpin springs into action and your thoughts stream away in all directions.[or]the Connection springs forth violently. You feel your awareness soak away into the surroundings, obliterating the boundary between yourself and the rest of the world.[or]tendrils of Connection leap from your mind, twining hungrily through the room.[or]gradually, every tiny detail in the room, every stain on the wall or mote of dust seems to jostle for your attention, coaxing your thoughts away. Your surroundings now shimmer with Connection energy.[in random order]";
  otherwise say "You raise your hand to your neck, [one of]then collapse with relief as the Connection dissipates. The world fades into normality.[or]and the Connection vanishes, leaving you feeling drained and nauseous.[or]and the Connection fades gradually. You rest awhile with your hands on your knees, waiting for the writhing black spider-legs to recede from the edges of your vision.[or]and your mind snaps back into your body with a jolt. You wait for a few breaths for the dizziness to subside.[in random order]";
  try looking;

Before going when the player is connected:
  say "[one of]You take a single step then fall to your knees, clawing at the floor in an attempt to stop the world spinning wildly around you. Coordinating your movements while Connected is like hauling at the strings of a tangled puppet; confusing and frustrating.[or]You find it impossible to move about while Connected.[stopping]";
  stop the action;

A thing can be known and unknown. Usually a thing is unknown.

Before examining:
  If the player is connected, now the noun is known;
  continue the action;

[The player can examine the thoughts of nearby people when Connected.]
After deciding the scope of the player when the player is connected: 
  repeat with nearby room running through rooms which are adjacent to the location 
  begin; 
    repeat with occupant running through people in the nearby room 
    begin;
      place occupant in scope;
   end repeat;
  end repeat.
  repeat with occupant running through people in the room 
  begin;
    place occupant in scope;
 end repeat;

[This rule means that you can Connect with any other living thing, no matter how far away it is.]
A procedural rule while looking when the player is connected:
  if the noun is a person, ignore the can't reach inside rooms rule.

A procedural rule while asking a person about something or telling a person about something or answering a person that something when the player is connected:
  if the noun is a person, ignore the can't reach inside rooms rule.

Report looking when the player is connected:
  repeat with nearby room running through rooms which are adjacent to the location 
  begin;
    if anybody is in the nearby room, say "You sense the presence of [a list of people in the nearby room] in [the nearby room]. You are close enough to examine their thoughts with the Connection.";
  end repeat;

Instead of answering the noun that something when the player is connected, try asking the noun about it.
Instead of telling the noun about something when the player is connected, try asking the noun about it.
Instead of asking the noun about something when the player is connected, say "You throw all the Connection energy you can muster at [the noun]. However, they cannot feel your presence. This was one of the first Connection teachings that you learnt: unless the target is another Master with their own brainpin, the Connection is strictly one-way."

before examining something unknown while the player is connected:
  if the noun is a person, say "You send forth tendrils of Connection to grasp the essence of the other's mind..."; otherwise say "You still your thoughts as you have been trained, then wait for unbidden Memories to rise from the depths of your mind...";
  continue the action;

Test connection with "touch head / touch skull / connect / activate"

Chapter 3 - Yourself

Instead of examining the player:
  say "[if the player is unconnected]You feel your body gingerly. You have many bruises and a huge lump on your skull that you sustained during your capture, but this is gentle treatment compared to what is usually meted out by the Hedonans. You are one of the toughest young priests in the Monastery, so a few bumps won't slow you down.[otherwise]What are you? A feeble spark of life, jostled amongst a billion others, a squirming bag of flesh. What sets you apart from from any other fragment of the universe?[paragraph break]Nothing. This is the bitter irony of life: you live in constant fear of being hurled into the oblivion of non-existence; yet the truth is, you never left it.[end if]";


At 9:10 AM: say "You feel a movement deep inside your body, like a fist settling its grip on your spine. Ever since you woke up you have been living in a half-dream, and unable to control your own actions. You must find the root of this influence before it consumes your mind completely, then make your escape.

Once again, the fist wraps firmly around your insides, and these troubling thoughts evaporate."

At 9:20 AM: say "You feel the squirming sensation in your spine once again. Is your brainpin malfunctioning? Your thoughts are no longer your own, and you have a chilling suspicion that the Ancients[apostrophe] artefact has been Activated. However, the influence seems to be benevolently guiding you towards escape. Perhaps it has been discovered by someone nearby, who shares your desire to flee? You send a mental acknowledgement to whoever or whatever has set this thrall upon you:

'Guide me to you and I shall release you, in exchange for my free will.'

As a reply, the influence settles about your spine once again, and you pursue these worrying thoughts no further."

Understand "shirt" or "cloak" or "trousers" as clothes.
Clothes are things. They are a backdrop and everywhere. "You are wearing the clothes that you were captured in: a heavy priest's cloak over a rough-woven shirt and canvas trousers."

People can be embarrassed.

[Otherwise the player may trigger special actions if they look at themselves the first time.]
The player is known.

[If the player is messing about then we give a stock response.]
Kissing someone is stupid behaviour.
Tasting someone is stupid behaviour.
Instead of stupid behaviour:
  say "That is hardly appropriate behaviour under the circumstances.";

Understand "examine room" as looking.

Understand "dance" as dancing. Dancing is an action applying to nothing.

Instead of dancing:
  say "You feel the sudden urge to prance about, throwing your legs in the air and twirling wildly. As quickly as it came, the feeling evaporates, leaving you feeling slightly embarrassed.";
  now the player is embarrassed;

Understand "sing" as singing.

Instead of singing:
  say "You take a deep breath and begin singing a stirring Monastery ballad. It sounds as bad as you feel.";
  now the player is embarrassed;

Understand "scream" or "yell" or "shout" as screaming. Screaming is an action applying to nothing.
Instead of screaming, say "You take a deep breath and give a throat-tearing scream. As the sound echoes down the corridors of the prison, you hope that nobody will investigate the commotion. Probably not; the sound of screaming would be common here."


Chapter 4 - Automating Obvious Actions

Understand "unlock [something]" as unlocking keylessly. Unlocking keylessly is an action applying to one thing.

Understand "lock [something]" as locking keylessly. Locking keylessly is an action applying to one thing.
Instead of locking keylessly, say "You might as well leave it unlocked - there's no reason to lock it."

Instead of taking something fixed in place:
  if the noun is furniture, say "It is too heavy to be moved.";
  if the noun is not furniture, say "That cannot be taken.";
  stop the action;

Before throwing something at something:
  say "You throw [the noun] at [the second noun] and it bounces harmlessly to the floor.";
  move the noun to the location;
  if the second noun is the defeated warden, say "The warden gives you a dark look. 'You are really trying my patience!'";
  stop the action;

Chapter 5 - Object Classes

Understand "light bulb" or "lightbulb/light/lights" or "bulb/bulbs" or "globe/globes" as lightbulbs.
lightbulbs are things. They are a backdrop and everywhere. "The compound is lit with electric lights. The bulbs dangle from metal wires enclosed in cloth sheaths. They are made of poorly hand-blown glass, with a feebly glowing filament inside."

Instead of doing something other than examining to the lightbulbs, say "They hang far above, out of your reach."

Furniture is a kind of thing that is a supporter and enterable and scenery.
Instead of entering furniture, say "You climb onto it, but see nothing unusual from the higher vantage point. You climb down again."

Instead of listening, say "It is late at night, and the only sound is the faint hum of electric light bulbs."

Corners are things. They are a backdrop and everywhere. "You look in the corner of the room, but there is nothing to be seen."

The floor is a thing. It is a backdrop and everywhere. "The floor is solid concrete."

Chapter 5 - Things You Know

Understand "remember [text]" or "think about [text]" as remembering. 
Remembering is an action applying to one topic. 

Carry out remembering: 
    say "You can't remember anything particular about it at the moment."


Instead of remembering a topic listed in the Table of Recollections: 
    say "[response entry][paragraph break]". 


Table of Recollections 
Topic    					Response    
"monastery/home"			"Nestled in a valley in the mountains, the Monastery has been your home for most of your life. It is the last island of reason in a world of ignorance and cruelty."    
"family/parents/mother/father"		"You can remember little of the time before you came to the Monastery. The priesthood is your family now."
"war" or "nuclear war"    	"Much of your schooling was on the Great Nuclear War. Before the War, enlightenment on a global scale was almost within reach. Afterwards - well, things have been a bit of a mess."
"hedona" 				"You have never been to Hedona - you have only heard the tales of other Masters who have been posted as spies there. The city is visible from your mountain home, sprawling over the plains below like a forest of grey pillars. Although the Hedonans are slowly making technological steps towards the culture of the pre-War world, it is in appearance only. They lack a higher purpose to lend direction to their activities, so their city will always remain nothing but a thin cement shell around a rotten core."
"hedonans"				"The inhabitants of Hedona are little more than cunning animals in human form. Lust and greed completely guide their actions, making them the enemies of the Monastery, and enemies of the higher goals of life itself."
"brainpin/connection/connecting" or "brain pin"	"[one of]The brainpin is the tiny sliver of metal that gives the Masters their powers. After a Master dies, his brainpin is passed on to his greatest pupil. Connection allows a greater awareness of the mental processes of other beings, and access to ancient wisdom beyond that of the individual's own experience. Although this experience is enlightening, and some would say, mystical, it is based purely on physical principles.

Your brainpin has two modes of operation: Connection and Memory. Connection allows a Master to examine the minds of others from almost any distance, and Memory can access fragments of pre-War data that is woven into the tissues of the user. Memory occurs automatically when a Master is Connected, and is triggered by visual cues in the environment.[or]Type 'connect' or 'c' to toggle your Connection ability on or off. You can now examine objects for further information, or read people's minds, even if they are far away.[stopping]"
"ancients"				"Unfortunately for the Ancients, their powers increased faster than their wisdom, and they wiped themselves out during the Nuclear War. The Ancient races are long gone, yet their philosophies continue to inspire the priesthood of Connection. The only physical evidence of the Ancients' existence are their ruins, their scattered Memories and their artefacts, including the small number of brainpins controlled by the priesthood. The Ancients are survived by their degenerate progeny: the vile Hedonans, and the normal folk who have been driven into the mountains by the Hedonans."
"resistance"				"You have heard tales of a group of Hedonans who have rebelled against the urges of their own flesh, and turned towards Reason. They work secretly within the city of Hedona to tear it down from the inside. However, these rumours are probably nothing more than comforting myths."
"master/masters/priests/priest"		"You are a Master priest of the Connection. You have refined your body and mind into the perfect instrument for defending and promoting the values of the Monastery: life and wisdom in all its infinite varieties and forms. You excelled in this task and are now the bearer of a brainpin, one of the greatest honours possible."
"bornware"				"Bornware: the double spiral of natural wisdom that is twisted into every cell of every living being. The Ancients enhanced their own bornware in ways beyond those discovered by nature, and fragments of their legacy still appear occasionally in the modern population."
"artefact/artefacts"			"The Ancients created many powerful devices, until they used them to destroy each other. Some superstitious common folk believe that Artefacts are magical, but the Masters know better. The Memory ability shows that they are nothing but devices, albeit incredibly advanced ones. Most Artefacts are useless and broken, with rare exceptions, such as brainpins.

Recently, however, there have been strange distortions of the Connection field, possibly caused by a recently activated artefact. You were one of a group of Masters who set off into the mountains to investigate, and were captured when you were attacked by a much larger band of Hedonans."
"prison guard" or "guard"			"[one of]You can use the Connection to read minds. The prison guard seems formidable, but everyone has a secret fear that can be turned against them.[or]The guard has a phobia of being burnt.[or]SPOILER: Go to the kitchen, then put the poker in the fire. You now have a red-hot object.[stopping]"
"warden"				"[one of]Once again, people are not always what they seem if you look inside their minds. You may have a friend, if only you can prove in a word or so that you know something only an ally could know.[or]The warden is a spy who fought a battle in mountainous country. Where have you seen that before? Maybe you could ask him about his past allegiances?[or]Ask the warden about the name of the army group he fought under, which can be found in the Guard's Quarters.[or]SPOILER: Ask warden about k3 division.[stopping]"
"supervisor"				"[one of]The Connection can reveal medical problems. The guard is hungry - maybe you could get him to eat something that he shouldn't?[or]Read the guard's mind, then have a look around the kitchen and try spiking some food. You might need some help fetching the supervisor afterwards.[or]SPOILER: Connect and examine the supervisor. Take peanut chips from the cupboard, then put them in the soup pot and tell the warden that the soup is ready. Get inside the cupboard and close the door, and wait for the action to begin. Now there are no guards around to bother you.[stopping]"
"door"				"[one of]The door in the Bunker was made by the Ancients - they would never be stupid enough to make a door that could trap occupants in the room. You can access the knowledge of the Ancients by CONNECT ing.[or]SPOILER: To open the bunker door, first CONNECT, and then EXAMINE DOOR. You can now open it.[stopping]"


Part 2 - the World

Chapter 1 - Guards

A guard is a kind of man. A guard is either defeated or undefeated. Guards are usually undefeated.

Every turn when fetching is happening or leaving is happening or trying soup is happening:
  if an undefeated guard can see the player, try waiting;
instead of doing something:
  if an undefeated guard can see the player
  begin;
    say "The guard slams a fist into your guts and you collapse as pain races through your body. You have no time to recover before you are wrenched to your feet and marched roughly to the bunker. He shoves you headfirst into the cell. [if the player carries the poker or the player carries the log book]

He notices the bulge under your cloak, and snatches back everything that you have stolen from the base.
[end if]

[one of]'I'll kill whoever it was that let you out of there!' [or]'Go on, just keep trying your dirty magic, you won[apostrophe]t get out of here alive!' [or]'Maybe next time I'll teach you a lesson you won't forget!'[or]'Don't you ever learn?' [or]'That's right - just keep escaping, and I'll just keep locking you up!' [or]'Let's keep going and see which gets sorest first: your ribs or my fist!' [or]'And stay there this time!' [stopping]he yells as he slams the door and locks it from the outside.";
    move player to bunker;
    if the metal door is open, silently try closing the metal door;
    now the metal door is locked;
    now the log book is in the guards quarters; 
    now the poker is in the kitchen.
    stop the action;
  end if;
  continue the action;

Instead of attacking an undefeated guard:
  say "Despite landing a solid punch under the guard's ribs, your fist bounces harmlessly off his heavy armour.";
  continue the action;

Understand "hit [something] with [something]" as attacking with an object. Attacking with an object is an action applying to two things.

Instead of attacking with an object:
  say "It would be pointless to attack it.";
  stop the action;

Instead of attacking with an object when the noun is a person:
  say "You swing at [the noun] with [the second noun], but he easily swats it out of the way. You are strong and fast, but no match for the huge guard. [if the noun is defeated]

'Watch it!' says the no-longer-so-[noun]. 'My patience with you is running out!'[end if]";
  stop the action;

Every turn:
  If somebody undefeated is in an adjacent room (called the nearby room)
  begin;
    say "[if trying soup is happening]You hear the tramp of heavy boots from [the nearby room].[otherwise]You hear [one of]breathing[or]the rustle of clothing[or]somebody humming[or]a cough[or]a yawn[as decreasingly likely outcomes] from [the nearby room] to [the best route from the location of the player to the nearby room].[end if]";
  end if;
  continue the action;

Chapter 2 - Metal Objects

A thing can be metallic or nonmetallic. Things are usually nonmetallic. A thing can be hot or cold.

Instead of inserting something which is metallic into a fire:
  If the noun is cold begin;
    say "You hold [the noun] in the fire until it is glowing a dull red.";
    now the noun is hot;
    if the noun is not held by the player, silently try taking the noun;
  otherwise;
    say "It[apostrophe]s already glowing red hot.";
  end if;
  stop the action;

Instead of taking something which is hot:
  say "[if the noun is held by the player]You are already holding it.[otherwise]You carefully grasp the cold end of [the noun].[end if]";
  now the noun is held by the player;
  stop the action;

Before printing the name of a hot metallic thing, say "red-hot "


Chapter 2 - People, rooms and objects

Section 1 - the Bunker

The Bunker is a room. The description is "[if unvisited]You lie motionless for a long time. The cold concrete floor beneath you and the throbbing of your bruises reminds you that you have not awoken in the familiar barracks of the Monastery.[paragraph break]You recall a bitter liquid being forced between your lips. Now you feel a strange influence pushing the drug-fog from your mind; your spine feels leaden and numb, as if it doesn't belong in your body.[paragraph break][end if][if the player is unconnected]The makeshift cell is dust-choked and filled with a jumble of machine parts, boilers and scrap metal. This room is old - much older than the Hedonan prison compound that has been built on top of it. Some of the debris looks like it has been here since the Nuclear War.[otherwise]The familiar sensation of Connection appears to fill the room with light, and the artefacts shimmer with a latent energy. Some are incredibly old, from another age, and their history sits heavily on them.[end if]

There is a metal door in the east wall."

The metal door is a closed locked door. It is scenery. The metal door is east of the bunker and west of the corridor. The description is "[if metal door is unknown]This massive door has been here since the original room was built, and it looks like it was designed to withstand anything that the Ancients could have thrown at it. From past experience you know that when you are Connected, the sight of old objects such as this often triggers Memories.[otherwise]It is a fallout shelter blast door, rated to fifty megatons and gamma shielded. Whatever that means.

There is a safety mechanism built into the door to prevent its occupants from being trapped in the event of a power failure. The switch is hidden in the frame of the door and marked clearly with labels (that must have long ago peeled off, you assume). You think you should be able to unlock it now, unless the guards have already discovered the button and disabled it.[end if]

[if the metal door is open]The door is open.[otherwise]The door is closed.[end if]
"

Walls are things in the bunker. They are scenery. "[if the player is connected]The walls vibrate with Connection energy, like many other structures that were built by the Ancients. A faint spidering of lines appear across your vision for a moment; possibly a map of the ancient structure, but the Memory is far too weak to be useful. Besides, the original building is now nothing but ruins - the Hedonan prison is a much more recent construction.[otherwise]The far wall is hewn out of solid rock, but the others are dense concrete, rust-stained by the gradual seepage of ground water.[end if]"

The ceiling is a thing in the bunker. It is scenery. "The ceiling is concrete, stained a dark rust-brown by a millennia of seepage."

Understand "scrap" or "boiler" or "boilers" or "parts" or "machine" or "artefacts" or "debris" or "jumble" as junk.
Junk is things in the bunker. It is scenery. "It looks like typical Nuclear War debris: ancient, mysterious, and crumbling into oblivion. You have no idea what it might once have been used for."

Instead of attacking door, say "You hammer at the steel door, but you could do so for a thousand years and it would not be damaged in the slightest."

Before opening the metal door:
  silently try unlocking keylessly the metal door;
  continue the action;

[Once the player connects, they can examine these useless objects.]
After connecting in the bunker:
  if the player is connected begin;
    repeat with memory object running through things in bunker storage begin;
      move memory object to bunker;
    end repeat;
  otherwise;
    move rat to bunker storage; [the rat is not detectable by any means now.]
  end if;
  continue the action;

After examining the metal door while the player is connected:
  move hidden switch to bunker;

Before unlocking keylessly the metal door when the metal door is locked:
  if the metal door is unknown
  begin;
    say "There seems to be no obvious way of unlocking the door from the inside.";
    stop the action;
  otherwise;
    try pushing the hidden switch;
  end if;

Instead of going to the corridor from the bunker when the unlocked metal door is closed:
  try opening the metal door;
  continue the action;

Instead of pushing hidden switch when the metal door is locked:
  say "You feel around the edge of the door and press the hidden button. There is a click as the door unlocks.";
  now the metal door is unlocked;
  stop the action;

Instead of pushing hidden switch when the metal door is unlocked, say "Operating the hidden switch does nothing, because the door is already unlocked."

Every turn when the player is in the bunker for the fifth turn and the player has not been connected:
 say "You sigh and slump against the wall. There is no obvious way out of here. You should try to use the powers of Connection instead of continuing this fruitless search. You can touch your head to Connect at any time, just as you do at home in the Monastery.";

test connected with "look at door / connect / look at door / look at rat / look at poker / press button / go east"

test hint with "z / z / z / z / z / z"

Section 2 - the Corridor

The Corridor is a room. The description is "[if the player is unconnected]The walls of this hallway were once covered in tiles but these have long ago fallen away, leaving square impressions in the crumbling grouting. Moonlight shines through a row of barred windows far above you, striping the concrete floor with shadow. 

To the west is the bunker that was unable to contain you. At the south end of the Corridor is a doorway, and the northern end opens into a much larger room.[otherwise]The Corridor heaves gently in your vision as if you are inside the ribcage of a sleeping serpent. A deathly silence pervades the air - the Connection finds no other living presence to grasp onto.[end if]"

Barred windows are things in the corridor. They are scenery. "The row of small windows is far above you. Their close-set bars frame the full moon, which hangs in a cloudless sky."

Impressions are things in the corridor. They are scenery. "They are square marks where tiles have fallen away, exposing the grouting beneath. The compound is built solidly, but little effort has gone into its upkeep."

Tiles are things in the corridor. They are scenery. "The fact that someone bothered to line this area with thousands of white tiles belies a sophistication beyond that of its current inhabitants. This building would have served a different purpose before it was overrun by the Hedonans. Now the tiles are dusty, cracked and mildewed."

Section 3 - the Guards' Quarters

Rule for printing the name of the guards quarters: say "Guards[apostrophe] Quarters".

The guards quarters is a room. The guards quarters is south from the corridor. "[if the player is unconnected]Three beds and a table are wedged into this small room, leaving little space for anything else. There is a single electric bulb burning dimly from the ceiling, which illuminates a couple of paintings fixed to the grimy, cracked walls. The odour of unwashed bodies and filthy bedclothes assaults your nostrils.[otherwise]The guards[apostrophe] quarters feels as though it has absorbed the degeneracy of those inside it, crumbling along with the spirits of its occupants.[end if]

The only exit in this room is the corridor to the north."

Paintings are things in the guards quarters. They are scenery. "Two paintings hang on the wall: one depicts a ship on a stormy sea, the other a mountainous battle scene."

Understand "ship" or "sea" as painting of the ocean.
The painting of the ocean is a thing in the guards quarters. It is scenery. "The painting shows a maritime scene: a huge sailing ship tossed upon a stormy sea. A banner flowing from the ship's mast bears the following script:

[italic type]'In memory of those of the Firelance Squadron who found peace in the ocean they loved. Your memory is as dear to us as ourselves.'[roman type]"

Understand "battle painting" or "mountain/mountains/mountainous" or "battle scene" or "battle" as painting of mountains.
The painting of mountains is a thing in the guards quarters. It is scenery. "This painting depicts a small group of soldiers manning a barricade and firing their rifles into hordes of enemies below. Behind them, grey peaks bite into a cloudy sky. A metal plaque on the frame of the painting reads:

[italic type]'Let us never forget the brave soldiers of K3 Division. All were lost while holding a mountain outpost against overwhelming odds for two days. Let us remember those who died while protecting our freedom.'[roman type]"

Understand "table" as desk.
The desk is a thing in the guards quarters. It is furniture. "The surface of the wooden desk is pitted with knife scratches and ink blotches."

Understand "bed/bags/straw" as beds. The beds are things in the guards quarters. They are furniture. "The beds are nothing but rickety wooden frames. Bags stuffed with straw serve as mattresses. The guards rotate shifts regularly, so each bed is probably used by many people, and judging by the musty smell of this room, changing bedding is not a priority."

Instead of looking under the beds, say "There is nothing beneath them but dust and hairballs."

Understand "roster" as the log book.
The log book is a thing in the guards quarters. The description is "[if the player is unconnected]The book records notable events in the prison: the food delivered and cooked, the number of guards on duty, the arrival of new prisoners and their eventual fates. The last few entries in the roster are:

[italic type]Seventh day of fifth moon - Pea soup - On duty: guards H117, L21, L266. Guard L21 disciplined for being excessively drunk on duty. Prisoners quiet.

Eighth day of fifth moon - Mutton leg - On duty: guards H117, M43. Large mobilisation of bandits in surrounding area, reason unknown. Reinforcements requested.

Ninth day of fifth moon - Vegetable and beef soup - On duty: guards G267, B21, M43. Two new prisoners, both brought in by Division investigating recent bandit activity:[line break]
 - Male outlaw, to be kept sedated and locked in the old storage room. Highly dangerous, probably possesses advanced bornware. Awaiting vivisection.[line break]
  - Civilian captured around the region of activity, hold for interrogation and execution.[roman type][otherwise]The words swirl unintelligibly on the page. You find it impossible to read such fine print while Connected.[end if]"

Section 4 - the Mess Hall

The Mess Hall is a room. The mess hall is north from the corridor. "[if the player is unconnected]This room contains a table and chairs, and smells of stale beer and rotten vegetables. It seems that this is where the guards come to eat and gamble in the evenings, but now it is deserted. The cement floor is sticky with trodden food scraps.[otherwise]You get little sense of Connection with this space - it seems that the guards manage to relax here somewhat, and their essence has not been so heavily absorbed into the walls. The ceiling seems impossibly high, as if its wooden rafters are holding up a dark, swirling sky of pine knots and whorls.[end if]

You can go to the east through a narrow archway. To the south is the corridor leading to the Bunker, and [if the kitchen is visited]the Kitchen[otherwise]another room[end if] is to the west."

Instead of examining the floor in the mess hall, try examining the food scraps.

In the mess hall are food scraps. They are scenery. "The floor is covered with spat seeds, vegetable peelings and other horrid refuse."

In the mess hall is a table. It is furniture. "There is a long table here. It is bolted together from rough wooden beams."

Understand "chair" as chairs.
In the mess hall are some chairs. They are furniture. "The chairs are long benches bolted to the tables."

Section 5 - the Kitchen

[TBD - the two rules below could be combined to make the code more elegant]
Before taking something when the player is inside the cupboard:
  if the noun is not inside the cupboard
  begin;
    say "(after getting out of the cupboard)";
    silently try the player exiting;
  end if;
  continue the action;

Before inserting something into something when the player is inside the cupboard:
  if the noun is not inside the cupboard or the second noun is not inside the cupboard
  begin;
    say "(after getting out of the cupboard)";
    silently try the player exiting;
  end if;
  continue the action;

Before exiting when the player is in the closed cupboard:
  try opening the cupboard;
  continue the action;

Before entering the closed cupboard:
  try opening the cupboard;
  continue the action;

Something can be dissolved.

The Kitchen is a room. The kitchen is west of the mess hall. "[if the player is unconnected]The kitchen is grease-spattered, smoky and warm, with a bench along the wall and a large wooden cupboard in the far corner. There is some soup cooking on a stone fireplace.[otherwise]Your attention is drawn to the fire, and the dance of its flames. It takes an endless succession of forms, always shifting, as if indecisively searching for an ideal state of being.[end if]

To the east is a narrow archway leading to the Mess Hall. To the north end of the Kitchen is a barred door which appears completely impenetrable, beyond which, a corridor continues into the gloom."

Understand "table" as bench.
In the kitchen is a bench. It is furniture. "The bench is made of solid pine, and a long plank serves as a seat. Its surface is stained with innumerable food spillages."

In the kitchen is a chimney. It is scenery. "The brick chimney leads up into the ceiling. It is much too narrow to squeeze into."

The wood pile is a thing in the kitchen. The description is "[if the player is unconnected]A few wedges of chopped firewood. The rich scent of pine tar reminds you of the forests around the Monastery.[otherwise]Faint Memories remain in the drying sap: moist earth, green-filtered sunbeams, leaves trembling in a spring breeze.[end if]"

Instead of inserting the wood pile into the fire:
  move the wood pile to general storage;
  say "You throw the logs onto the fire, and it crackles with renewed vigour.";
  stop the action;

The barred door is a closed locked door. The barred door is north of the kitchen. It is scenery. The description is "The corridor to the north is blocked by a sliding barred door, fitted with a very solid-looking lock. The unlit corridor beyond is lined with many doors, which are eventually lost in murky darkness."

In the kitchen is a lock. It is scenery. "The lock takes a key - there is no other way to open it."

Instead of unlocking keylessly the barred door, try examining the lock.
Instead of unlocking keylessly the lock, try examining the lock.
Attacking the lock is breaking out.
Attacking the barred door is breaking out.
Instead of breaking out, say "You shake at the metal bars, but they are completely solid. There is no way through here."

In the kitchen is a cupboard. A cupboard is a container and scenery. The cupboard is closed and openable and enterable. The cupboard is lit. "The cupboard has plenty of room inside for the guard's cooking supplies. None of this is for the prisoners - they only get raw vegetables and soaked grain."

After examining the open cupboard:
  say "Inside the cupboard there are [a list of things which are inside the cupboard].";
  continue the action;

Understand "spices" as herbs.
Some herbs are things that are fixed in place. The description is "[if the player is unconnected]There are dozens of small jars here. You don't know much about herbs. Back at the Monastery, the cooks believe that fleshly appetites should be discouraged, so unnecessary spices are not used in cooking.[otherwise]The herbs still have a lingering Connection to the land where they were grown. Some remind you of moist, earthy forest floors; others of blazing sun and shifting sand.[end if][If the peanut chips are in the cupboard] You notice a jar of peanut chips in amongst the other herbs.[end if]". The herbs are in the cupboard. 

Instead of searching the herbs, try taking the herbs.
Instead of taking the herbs, say "There are dozens of jars here filled with leaves and powders of every colour, most of them without labels. You have no idea which ones could be useful."

Instead of tasting the herbs, try smelling the herbs.
Instead of smelling the herbs, say "You select a jar at random, unscrew the lid, and hold it beneath your nose. [one of]The pungent aroma makes you think of sun-parched, faraway lands. [or]The smell reminds you of a time long ago; before your hard life at the Monastery began, and when your family was still alive. [or]The fumes from the red powder claw at your nostrils and make your eyes sting. [at random]You put the jar back on the shelf."

Understand "fireplace" as fire.
A fire is a container. In the kitchen is a fire. The fire is fixed in place and scenery. "[if the player is unconnected]A bed of coals glows and crackles in the open fireplace, and the smoke disappears up a chimney.[otherwise]You can almost see a faint rainbow aura around the flames, as if they had some living energy of their own. The coals shimmer and wink mysteriously. How could you have never noticed such beauty in fire before?[end if]"

In the kitchen is a poker. The poker is a metallic thing. The description of the poker is "It is an iron poker for tending the fire."

Understand "dinner" or "food" as soup pot.
Instead of drinking the soup pot, try eating the soup pot.
Instead of searching the soup pot, try examining the soup pot.
In the fire is a soup pot. A soup pot is a thing that is scenery and a container. "A pot of thick soup sits on the edge of the fire.[If the warden is in the kitchen] 'Just tell me when it's ready and I'll get the others,' says the warden.[end if]"

Instead of pushing the soup pot, say "That would be a waste of good food."

After inserting the peanut chips into the soup pot:
  move empty peanut chip jar to the player;
  now the peanut chips are dissolved;
  say "You empty the entire jar of ground peanuts into the soup pot.[If the warden is in the kitchen][line break]'Smells good!' says the warden.[end if]";

Instead of taking the dissolved peanut chips, say "It's too late - they're thoroughly stirred in."

Instead of inserting something nonmetallic into the fire, say "Why bother? [The noun] would only get burnt."

Fetching is a recurring scene.
Fetching begins when the warden is informed.
Fetching ends when the warden is in the front office.
Every turn when fetching is happening:
  Let the way be the best route from the location of the warden to the front office, using doors;
  try the warden going the way;

Instead of smelling the soup, say "You lean over the pot and inhale a delicious aroma of fresh vegetables, pungent spices and meat."

Instead of tasting the soup, say "The soup looks delicious, but your vows forbid you from eating flesh. If only the chunks of meat weren't so obvious..."

Instead of taking the soup, say "You have nothing to put it in."
Before eating the soup:
  try tasting the soup;
  stop the action;

When fetching begins:
  say "'I'll go to the cells and get the others.' the guard says, getting to his feet. 'You might want to get out of here before they arrive.'";
  now the warden is not informed;

Coming back is a recurring scene. Coming back begins when fetching ends.
Coming back ends sucessfully when the warden is in the kitchen.
Every turn when coming back is happening:
  let the way be the best route from the location of the warden to the kitchen, using doors;
  try the warden going the way;
  try the supervisor going the way;

Trying soup is a recurring scene. Trying soup begins when coming back ends.
Trying soup ends sucessfully when the warden is in the kitchen for two turns and the peanut chips are in the soup pot.
Trying soup ends unsucessfully when the warden is in the kitchen for two turns and the peanut chips are not in the soup pot.
Leaving is a recurring scene. Leaving begins when trying soup ends unsucessfully.
Leaving ends when the warden is in the Front Office.
Every turn when leaving is happening:
  let the way be the best route from the location of the warden to the front office, using doors;
  try the supervisor going the way;

When trying soup ends sucessfully:
  say "[If the player is in the mess hall or the player is in the cupboard]From your hiding place, you clearly hear [otherwise]From the direction of the kitchen you can barely hear [end if]the two men exchange a few gruff words, then the clank of a ladle in the soup pot. The ladle drops with a clatter, and the supervisor's furious swearing soon thickens into laboured gasps. There is the sound of keys rattling in a lock, and the metal gate to the rest of the compound screeches open then slams shut. The commotion gets softer as the warden rushes his stricken comrade to the infirmary in another wing of the compound, then all is quiet.";
  move the warden to general storage;
  move the supervisor to general storage;

When trying soup ends unsucessfully:
  if the player is in the mess hall or the player is in the cupboard, say "From your hiding place, you hear the ladle scraping in the soup pot. 'Ugh!' the supervisor splutters. 'It's still cold! Call me when it's ready!'

He slams down the ladle.";

Instead of inserting something hot into the soup pot:
  say "There is a furious hissing as [the noun] hits the soup.";
  now the noun is cold;
  continue the action;

Test cooking with "open cupboard / take peanuts / put peanuts in pot / tell guard about food"

Section 6 - Interrogation Chamber

To say number of padded cells empty:
  say "[if the prison guard is defeated]three[otherwise]four[end if]"

The Interrogation Chamber is a room. The interrogation chamber is east of the mess hall. The description is "[if the player is unconnected]A couple of dull-orange electric globes hang from the ceiling, filling the gloom with more shadows than light. There are [number of padded cells empty] empty cells leading off the main chamber, all of which have been lined with soundproof padding. An array of metal instruments hang on the wall, glinting in the half-light, and a coiled rubber cable lies on the floor.[otherwise]The air is thick with the terror of interrogation victims. There is a faint momory-echo of screaming, just on the edge of your hearing, like the memory of a nightmare upon waking.[end if]

There are archways leading east and west."

Understand "implements" as instruments.
Instruments are things in the interrogation chamber. They are scenery. "You can only imagine what these evil-looking knives and implements are for."

Understand "wire/wires" as the rubber cable.
The coiled rubber cable is a thing in the interrogation chamber. It is scenery. "The black rubber cable is long enough to reach into the cells when uncoiled, and has two bare wires protruding from its end."

Instead of doing something other than examining to the coiled rubber cable, say "You touch the cable gingerly. Sparks spit from the bare wires, and the rooms[apostrophe] lights flicker. It's too dangerous to pick up."

Cells are things inside the interrogation chamber. They are scenery. "The cells are padded and soundproof. This must be so that prisoners can be interrogated without disturbing the guards[apostrophe] sleep."

Instead of taking instruments, say "They are locked to the wall. The Hedonan guards may be stupid, but not stupid enough to leave their weapons lying around."

In the interrogation chamber is a prison guard. The prison guard is a guard. The description is "[if the noun is unknown]He is a skinny man with a puckered scar on his face.[otherwise]The man's mind is a dense ball of hate, flinching away from any Connection with other beings. Piercing his tough shell of malevolence, you uncover what it is protecting: a deep, repressed terror of something best forgotten. A painful memory flashes through your mind, as if from your own childhood - screaming and the licking of flames, the hiss of burning flesh. You recoil from the hideous phobia.[end if]"

The padded door is a closed door in the interrogation chamber. The padded door is north of the interrogation chamber and west of the padded cell. The padded door is scenery. "[if the prison guard is defeated]The door to the padded cell is closed and bolted, with the prison guard safely on the other side.[otherwise]The door leads to a padded, soundproof cell.[end if]"

Instead of opening the padded door:
  say "[if the prison guard is defeated]The guard is safely locked in the padded cell. You'd better leave him there.[otherwise]The guard stands between you and the door - there is no way you can reach it.[end if]";
  stop the action;

Every turn:
  If the prison guard in the interrogation chamber can see something that is hot
  begin;
    say "The guard swears in surprise, then freezes as he notices the red-hot object you are holding. His eyes bulge and he scrabbles for an escape, whimpering in terror. In his panic he backs into the cell behind him, and you slam the door and throw the bolt before he realises his predicament. You can barely hear his muffled yells from the other side of the padded door.";
    now the prison guard is defeated;
    now the printed name of the prison guard is "terrified guard";
    move the prison guard to the padded cell;
  end if;

Instead of examining the defeated prison guard, say "You cast your Connection through the padded door to embrace the mind of the guard trapped on the other side. You can only guess at the traumatic events which caused the guard's phobia of hot metal, but you are definitely the reason for the blinding rage that has now supplanted it."


Section 7 - Prison Wing

The Prison Wing is a room. The Prison Wing is east of the interrogation chamber. "[if the player is unconnected]The Prison Wing is lined with iron cages which stretch from floor to ceiling like cow stalls. They are empty. The floor is cold cement, and the walls are windowless and bare. [otherwise]The walls seem to press in on you, cramming your awareness into a solid core. You feel alone in the world, your Connections turned in on themselves, searching vainly for another.[end if]

You can see the Interrogation Chamber is to the west, and [if the Front Office is visited]the Front Office[otherwise]another room[end if] through an archway to the south."

Understand "cells/cages" as Prison Wing doors.
Prison Wing doors are things in the Prison Wing. They are scenery. "The doors are made of solid metal bars and are locked securely. You shudder at the thought of being locked up here like an animal."

In the Prison Wing is a warden. The warden is a guard. The warden can be informed. The description is "[if the warden is in the kitchen]The warden sits at the bench, idly cleaning his nails with a splinter of wood. He catches your eye, and nods to you conspiratorially. [end if][if the player is unconnected]He is a natural giant, and his armoured jacket swells him to terrifying proportions.[otherwise]This guard's mind feels different from that of the other Hedonans. He is physically huge, and this is the root of his radiant confidence. This is a man who knows no fear and feels no need to force his insecurities onto others. He is quite normal, in fact. You wonder how he could have fallen in with the Hedonans.

You try to transfix the guard's mind with tendrils of Connection, but they pass straight through. It feels as if the Hedonan warden is a thin, deceptive skin stretched over a second, deeper personality. You find yourself reliving a vivid memory.

[italic type]The sound of gunfire tears at your eardrums, deadening the screams of those around you. Beyond the sandbagged barricade, the valley flickers with the flash of rifles from concealed attackers. Only one Hedonan will survive the bloody combat: you. You were the one who betrayed the unit's strength and combat readiness to the Resistance. If all goes according to plan, you will soon be the lone soldier 'missing-in-action'. No doubt you will eventually re-enlist under a different name in order to commit future infiltrations.[roman type][end if]"

Telling literally is an action applying to two things.
Understand "tell [someone] [anything] is ready/done" as telling literally.
Telling literally is speech.
Asking someone about something is speech. 
Telling someone about something is speech. 
Answering someone that something is speech. 

Instead of speech when the noun is the warden:
  If the player's command includes "k3"
  begin;
    if the warden is undefeated 
    begin;
      say "The words freeze the guard as he moves to attack you. 'How do you know about K3?' he whispers. 'We made sure there were no witnesses!'

He claps a huge hand on your shoulder. 'I don't know what you're doing here, but I'll stay out of your way.' He glances nervously down the corridor. 'Do whatever you have to, but don[apostrophe]t speak of the Resistance again. If you are captured, kill yourself before you betray me!'

He heads towards the kitchen.";
      now the warden is defeated;
      now the printed name of the warden is "friendly warden";
      move the warden to the kitchen;
    otherwise;
      say "The warden looks away. 'Some things are best left unmentioned,' he says through gritted teeth.";
    end if;
    stop the action;
  otherwise; [player has not mentioned k3]
    If the warden is undefeated
    begin;
      silently try waiting;
    otherwise;
      If the player's command includes "food/soup/dinner/ready"
      begin;
        now the warden is informed.
      otherwise;
        say "'What?' the warden asks, with an uncomprehending scowl.";
      end if;
    end if;
  end if;

Instead of attacking the defeated warden, say "You swing a punch at the warden, but he responds instantly, slapping your fist away as if it were an insect. 'Don't try my patience!' he says with a snarl."

Test flashback with "tell the warden about the k3 Division/ask the warden about k3".

Section 8 - Front Office

The Front Office is a room. The description is "[if the player is unconnected]This room has cracked cement walls, painted over with flaking whitewash, illuminated by faintly flickering electric lights. A desk faces the southern entrance of the prison compound.[otherwise]You are in the entrance to the prison complex. All life seems to have fled from here, leaving a void in the Connection that is cold and numb.[end if]

To the west is a cell door which has been reinforced with heavy iron bars, to the north is the Prison Wing, and a raised iron door to the south leads outside."
The Front Office is south of the Prison Wing. 

In the front office is an office desk. It is furniture. "It is a sturdy oak desk, probably stolen from a wealthy household in a nearby village."

In the front office is a chair. It is furniture. "It is an imposing wooden chair with vine-like carvings and a faded velvet cushion."

In the Front Office is a supervisor. The supervisor is a guard.

Instead of examining the supervisor when the player is connected:
  say "Like everybody, the supervisor keeps his greatest fears deeply hidden. However, it doesn't take you long to crack through his tough facade and find the chronic anxiety beneath. 

This is not a nightmarish, irrational terror, but an alertness to a threat which is always present. Something as simple as eating could become a disaster for this man. Something as simple as eating peanuts.";
  if the peanut chips are in general storage, move the peanut chips to the cupboard;
  stop the action;

Section 9 - High Security Cell

The High Security Cell is a room. "[if the player is unconnected]The cell is solid concrete, with a heavy barred door that can be locked from the outside. There is someone sitting here holding a box covered in buttons.[otherwise]The room pulses with Connection energy, emanating in a blinding stream from the stranger in the corner of the room.[end if]

The only way out is a door to the east."

The cell door is a closed door. It is scenery. The cell door is east of the high security cell and west of the Front Office. "This door has been welded together out of heavy steel bars."

Understand "person" or "prisoner" as stranger.
The stranger is a man in the high security cell. He is scenery. "[if the player is unconnected]The stranger periodically looks up at you, then taps at the buttons on the device. They have a look of guilt about them, as if you have caught them in an uncomfortable situation.[otherwise]You reach for the stranger's mind, but a massive blast of Connection energy throws you back. Something nearby them is making a huge disruption in the Connection field.[end if]"

Instead of attacking the stranger, say "Filled with an inexplicable rage, you rush forward to attack the stranger. However, they have already scrambled out of the way. It is as if they knew what you were about to do before the thought had even crossed your mind."

Instead of speech when the noun is the stranger, say "The prisoner mouths your exact words as you say them."
Understand "box" or "computer" or "device" or "machine" as a manual uplink terminal. The manual uplink terminal is a thing that is in the high security cell and scenery. The description is "[if the noun is unknown]It's a black box: a War artefact, judging by its appearance. A green glow emanates from its top surface, and rows of buttons are arranged beneath. You lean over his shoulder to read the writing which moves down the top of the box... You lean over the stranger's shoulder to read the writing which moves down the top of the box... You lean over his shoulder to read the writing which moves down the top of the box... You lean over his shoulder to read the writing which moves down the top of the box...

Horrified, you tear your eyes away from your own thoughts mirrored in writing.[otherwise]The machine crackles with a malevolent force. You drop to the floor gasping, your thoughts torn apart by a whirling vortex of pure Connection. The Memory kicks in immediately: this is a uplink terminal, used for manually Connecting to local DefenceNet nodes. The words are just more garbled Memories from the recesses of your mind, but they bring dangerous, unholy thoughts with them.[end if]"

Before doing something: 
  If the stranger can see the player, say "You see the person in front of you press some buttons in quick succession..."

Instead of taking the manual uplink terminal:
  try attacking the manual uplink terminal;


Section 10 - Plain

The Plain is a room. "[if the player is unconnected]The black walls of the prison rise up behind you, and boundless flatlands stretch all the way to distant mountains which cut the horizon. A breeze brings the scents of night-pollen and earth, and stirs the moon-flecked sea of grass. A road to the east beckons you towards freedom and safety in the mountains.[otherwise]A thousand tiny minds flicker in the grass like sparks from a wildfire - insects and nocturnal mammals. Even the grass itself seems to throb faintly with its own cloudy awareness.[end if]"

Instead of going east in the plain:
  say "With each step, the prison falls away behind you, and the malign influence on your mind grows fainter. Finally, your head clears, and you become conscious of your whereabouts. The Monastery is a long day's journey into the mountains beyond, so you set off with renewed vigour.

---

[italic type]Your heart sinks as the green glow fades from the black box - the ability it had to control his mind must only work over a limited distance. You sent the priest towards the safety of the mountains - you hope that honour will compel him to find reinforcements, then return to save you. You hear the clatter of heavy boots in the corridor outside - it may already be too late for you.[roman type]";
  end the game saying "You have freed the Connection priest, but you remain imprisoned.";
  stop the action;

 The Plain is south of the Front Office.


Section 11 - Padded Cell

[The player should never reach here, it is only for the guard to be held in.]
The Padded Cell is a room. the padded door is south of the padded cell.

[connecting has some sort of penalty?]

Chapter 3 - Items Reserved For Later	
	 
[Items that appear inside the world later on are kept in "limbo" here.]

General storage is a container.

Understand "lever" or "button" as switch.
The hidden switch is a thing that is in general storage. It is fixed in place. The description is "The button is flush with the edge of the door, so you would never have noticed it if it wasn[apostrophe]t for the Memory. The Hedonan brutes who locked you in here have no idea that the door can be opened from the inside."

Understand "peanuts" as peanut chips.
Some peanut chips are things that are in general storage. The description is "[If the peanut chips are in the soup pot][The peanut chips] are well stirred into the soup.[otherwise]A small jar of finely crushed [peanut chips].[end if]"

Instead of smelling the peanut chips, say "It smells like the biscuits that are made in your home town's bakery."

Instead of eating the peanut chips, say "You take a small piece and chew it. They're definitely peanuts."

The empty peanut chip jar is a thing that is in general storage. "This is a small jar of cheap, cloudy glass. It once contained peanuts, but you've poured them all into the soup."

Bunker storage is a container. 

[Bunker items are stored here until Activation is first used. Then they are all moved en masse to the bunker room.]

Understand "metal cylinder" or "cylinder" as a microfactory array. The microfactory array is a metallic thing in bunker storage. The description is "[if the noun is unknown]It's a dull metal cylinder as big as your fist, with a honeycomb of small holes through its centre.[otherwise]Thanks to your Memory ability, you know that this is an omnicannon microfactory array. It was a part of many pre-Nuclear War weapons, and allowed the rapid breakdown and molecular assembly of a whole range of substances, including explosives. After thousands of years, like most other artefacts you have ever seen, this delicate device is now just junk from a long-forgotten era - completely useless.[end if]"

Rule for printing the name of the unknown microfactory array: if the microfactory array is unknown, say "metal cylinder";

Instead of switching on the microfactory array, say "[The microfactory array] appears to be nothing more than a cylindrical honeycomb of heavily tarnished metal. Moreover, it is clogged with dirt.[if the microfactory array is known] The Ancients undoubtedly had some lofty use for it, but now it is just junk.[end if]"

Understand "rusted box" or "box" as a plasma welder. The plasma welder is a thing in bunker storage. It is fixed in place. The description is "[if the noun is unknown]It's a rusty old metal device, as big as you and shaped like a giant version of the guns you have seen the Hedonan soldiers carrying. You have no idea what it could be.[otherwise]The sight of the object has triggered a distant Memory. It is, or rather was, an RX500 plasma welder. It was used for cutting and fitting heavy armour. Now it is useless, having spent an eternity rusting away in this room.[end if]"

Rule for printing the name of the unknown plasma welder: if the plasma welder is unknown, say "rusted box";

Instead of doing something other than examining the plasma welder, say "It's just a piece of junk now - completely useless for anything."

The rat is an animal that is in bunker storage. The description is "The Connection allows you to sense a hazy awareness nearby: the lazy swirl of simple thoughts and the warm contentedness of a full belly. It's a rat, its mind diffused by sleep. It is no doubt dreaming of food."

Instead of answering the rat that something, try asking the rat about it.
Instead of telling the rat about something, try asking the rat about it.
Instead of asking the rat about something, say "You throw all the Connection you can muster at the rat in a deafening mental shout, but the rat completely ignores you. The rudimentary Connection hardware in the nervous system of most living things is too weak to receive signals from a brainpin. You learnt this in elementary Connection theory, but it is irresistible to try doing it occasionally."

Instead of doing something other than examining the rat, say "The rat is safely curled up asleep behind a wall somewhere - you have no way to reach it."

test objects with "turn welder on"

Chapter 4 - the Ending

Before attacking the manual uplink terminal:
  say "You take the box from the unresisting hands of the stranger and examine it. Could this be the source of the strange Connections that the Monastery has been tracking for days? This machine must not be allowed to survive: experiencing the thoughts of others nurtures empathy and wisdom, but the ability to control minds breeds corruption. You hurl it to the ground...[paragraph break]
---

[italic type]There is a loud bang and a cloud of acrid smoke, and pieces of the artefact bounce everywhere. The Connection priest, your rescuer-by-proxy, jumps as if startled out of a daze.

'We must flee, my friend!' he says as he helps you to your feet. 'I am sure I need no introduction.'

He pauses at the door to the cell. '[if the player is embarrassed]I do not appreciate being made a fool of - you are lucky that I won't thrash you for what you forced me to do back there! [otherwise]Thank you for not making me do anything too embarrassing. [end if]Now let's get out of here before the Hedonans get back!'[roman type]";
  end the game saying "You escape from the prison compound with the Connection priest.".

Part 3 - Interface Tuning

When play begins:
	change left hand status line to "[location] exits: [exit list]";
	change right hand status line to "Connection: [connection status]".

To say exit list:
	let place be location;
	repeat with way running through directions
	begin;
		let place be the room way from the location;
		if place is a room, say " [way]";
	end repeat.

Rule for printing the name of a direction (called the way) while constructing the status line:
	choose row with a heading of the way in the Table of Abbreviation;
	say "[shortcut entry]".

Table of Abbreviation
heading	shortcut
north		"N"
northeast	"NE"
northwest	"NW"
east		"E"
southeast	"SE"
south		"S"
southwest	"SW"
west		"W"
up		"U"
down		"D"
inside		"IN"
outside		"OUT"

To say connection status:
  if the player is connected
  begin;
    say "ON";
  otherwise;
    say "OFF";
  end if;

Use no scoring. Use full-length room descriptions.

Understand "hint" or "help" as a mistake ("Trying to EXAMINE objects and people often gives an interesting result if you CONNECT first - your Connection abilities are not limited by distance.[paragraph break]If you get stuck, or even just want to know more about any concept, try typing 'THINK ABOUT (the object, person or action that has you confused)'. The more times you repeat thinking about something, the bigger the insights you will get, until you get an absolute giveaway."). 

Understand "use" or "use [something]" as a mistake ("Using is too general an action - you need to be more specific when describing what you want to do with something.").
Understand "credits" or "about" as a mistake ("Written by James Hudson (c)2007-2008. May be distributed non-commercially and modified, as long as the original author is credited. Testing by Dan Shiovitz, Leslie Viljoen  and S. John Ross.").
Understand "remember" as a mistake ("Be more specific about what you want to remember.").
Understand "think" as a mistake ("You ponder the nature of the universe in general - perhaps you should be more specifc about what you want to think about.").

[Source acknowledgements: Some code based on that of the Inform 7 documentation.]

[ VERSION HISTORY -

0.8
  FIXED - added hints in the world
  FIXED - strange warden behaviour fixed, disembodied talking

0.7
  FIXED - kitchen bench responds to table.
  Improved hint system, gives progressive hints on puzzles.

0.5
 connect-1-dan.txt transcript integrated
 connect-sjr-new-001-004.txt transcript integrated

0.4
 FIXED - spelling errors, to UK english
 FIXED - shortened intro

0.3
 FIXED - Traditionally room names are capitalized, not lowercase
 FIXED - The doors ought to be scenery, not static, so they don't show up in
   the room description
 FIXED - Exits ought to be listed in the room description, not just the status
   line (thinking of the mess hall in particular here)
 - Every item mentioned in the room description ought to be implemented
   (and this includes the vocab word 'paintings' for the two paintings,
   since that's how they're referred to in the room desc)
 FIXED - It'd be nice if >DISCONNECT was implemented along with >TOUCH SKULL
   (for that matter, I don't see an obvious reason not to let people move
   from room to room while connected)
 FIXED - It's a little unintuitive for me that >PUT POKER IN FIRE actually
   moves the poker into the fire -- I expected it to just heat the tip
   without me losing my grasp on it.]